Le plus intelligent, solutions plus efficaces pour l’importation, Exportation et récupérer toutes vos données de messagerie Outlook.

Exportation de courriels d’Entourage vers Outlook

Article par Dave Addey

J'ai récemment dû exporter un tas d'e-mails à partir d'Entourage et dans Outlook, afin de les envoyer à quelqu'un dans un format qu'ils peuvent parcourir et lire sur un PC. On pourrait penser que l'exportation d'une sélection d'e-mails d'un outil de gestion de messagerie Microsoft à l'autre serait facile, droite? Malheureusement pas. Heureusement, un peu de Applescript et un utilitaire relativement pas cher a des choses à travailler pour moi. Ce message décrit comment.

Le principal problème est l'absence d'un format commun entre Entourage (.Mbox pour les dossiers, .EML des e-mails individuels) et Outlook (.pst pour tout). Il y avait un très bon outil d'exportation AppleScript pour l'exportation à partir d'Entourage, mais malheureusement, il n'a jamais été mis à jour pour travailler sur Leopard. Vous pouvez exporter un dossier entier comme un fichier MBOX à partir d'Entourage, mais ceux-ci ne peuvent pas être ouverts par Outlook et ne sont donc pas très utile soit.

(En aparté, il existe de nombreuses façons de suivre la autres façon, d'exporter à partir d'Outlook et importer dans Entourage. Il est presque comme si beaucoup de gens passent de PC à Mac, mais peu besoin d'aller dans l'autre sens ...)

Ma solution finale comporte deux parties - recevoir du courrier sur Entourage, puis obtenir dans Outlook.

Obtenir envoi postal d'Entourage

Pour cette partie, J'ai écrit un Applescript (basé en grande partie sur un code de macosxhints) d'exporter tous les e-mails actuellement sélectionnés dans Entourage dans un dossier sur mon Mac. Un grand merci à l'utilisateur de macosxhints golgi_body pour l'affichage du code d'origine.

Voici le script que je utilise (Copiez ceci dans Script Editor pour l'utiliser):

tell application "Microsoft Entourage"
    -- get a reference to all selected messages from entourage
    set selectedMessages to the current messages
    if selectedMessages is {} then
        return
    end if

    -- absolute reference to our export folder
    set fpath to "DiskName:Users:myusername:Documents:existingfolder:"

    repeat with i in selectedMessages

        set sentDate to time sent of i
        set fname to fpath ¬
            & my padNumber(year of sentDate as integer) ¬
            & "-" & my padNumber(month of sentDate as integer) ¬
            & "-" & my padNumber(day of sentDate as integer) ¬
            & "-" & my padNumber(hours of sentDate as integer) ¬
            & "-" & my padNumber(minutes of sentDate as integer) ¬
            & "-" & my padNumber(seconds of sentDate as integer) ¬

        tell application "Finder"
            if (exists file (fname & ".eml")) then
                set k to 1
                repeat while (exists file (fname & "-" & (k as string) & ".eml"))
                    set k to k + 1
                end repeat
                set fname to (fname & "-" & (k as string))
            end if
        end tell

        set fname to fname & ".eml"
        save i in fname
        tell application "Finder" to update file fname

    end repeat

end tell

to padNumber(theNumber)
    if theNumber is less than 10 then
        return "0" & theNumber
    else
        return theNumber
    end if
end padNumber

Vous devrez définir fpath être le chemin vers un dossier existant sur votre Mac. Lorsque vous exécutez ce script dans Script Editor, tous les fichiers sélectionnés dans Entourage sera exportée vers votre dossier d'exportation sous forme de fichiers .eml.

Pourquoi utiliser AppleScript du tout? Pourquoi ne pas simplement faire glisser les e-mails sélectionnés sur un dossier? Après tout, Entourage invite ce les exporter lui-même au format .eml. Le problème est, quand vous le faites, Entourage exporte les e-mails en utilisant l'objet du courriel comme nom de fichier. Cela peut contenir toutes sortes de personnages étranges et merveilleux, et Windows n'aime pas du tout. Ce script permet d'éviter le problème en utilisant à la date et l'heure courriel a été envoyé comme nom de fichier. (Il rend également plus facile de commander vos fichiers .eml par date et heure dans le Finder si vous avez besoin.)

Obtenir courrier dans Outlook

Pour cette partie, J'ai utilisé un utilitaire Windows appelé Assistant Importation Outlook. Ça coute $19.95, mais il est plus que la peine si l'on considère le temps qu'il peut sauver. Vous pouvez le télécharger et l'essayer gratuitement (max 5 e-mails par démonstration import), mais attention - en mode démo, vous ne pouvez pas activer la case « Activer la pré-traitement EML (UNIX, MAC)» Option pour faire reconnaître l'assistant des e-mails codés Mac, et ainsi vos e-mails importés contiennent beaucoup de symboles « = » lorsque vous les affichez dans Outlook. Les bonnes nouvelles sont que l'application achetée fonctionne très bien avec des e-mails codés Mac.

Le processus d'importation est assez facile. Sur votre PC avec Outlook installé, travailler dans l'Assistant Importation d'Outlook, être sûr d'activer la case « Activer la pré-traitement EML (UNIX, MAC)option « (sous le bouton « Options » sur l'écran « Sélectionnez le dossier source ») pour vous assurer que vos e-mails codés Mac sont reconnus. L'assistant est assez explicite, et il y a instructions complètes en ligne, donc je ne vais pas courir le reste des réglages en détail ici. Ça va prendre un certain temps pour faire l'importation, mais finalement vous finirez avec tous vos e-mails dans Outlook, avec toutes les pièces jointes et les en-têtes originaux.

Je n'ai essayé moi-même avec ce processus Entourage 2008 (sur Leopard) et Outlook 2002 (sur XP), mais je pense que cela fonctionne avec les versions antérieures d'Entourage aussi. L'Assistant d'importation d'Outlook prétend fonctionner sous Windows 98 / Me / NT 4.0 / 2000 / XP / 2003 avec Outlook 98/2000/2002/2003/2007, de sorte que vous devriez être bon d'aller, peu importe ce que votre configuration.