Eksportē e-pastus no Entourage uz Outlook

Pants Dave Addey

Man nesen bija eksportēt ķekars e-pastus no Entourage un Outlook, lai nosūtītu tos kādam formātā tie var pārlūkot un lasīt uz datora. Jūs domājat, ka eksportēt izvēli e-pastus no vienas Microsoft e-pasta vadības instruments, lai vēl būtu viegli, pa labi? diemžēl nav. Par laimi, mazliet AppleScript un salīdzinoši lētu lietderība ieguva lietas strādā par mani. Šis amats ir aprakstīts, kā.

Galvenā problēma ir, ka nav kopēju formātu starp Entourage (.mbox mapes, .eml atsevišķu e-pastu) un Outlook (.pst par visu). Agrāk eksportēšanai no Entourage bija patiešām labs Applescript eksporta rīks, bet diemžēl tas nekad nav bijis atjaunināts strādāt Leopard. Jūs varat eksportēt visu mapi kā MBOX failu no Entourage, bet tie nevar atvērt ar Outlook un tāpēc tie nav daudz, vai nu.

(Kā malā, ir vairāki veidi, kā iet cits veids, eksportēt no Outlook un importēt Entourage. Tas ir gandrīz kā tad, ja daudz cilvēku pāriet no PC uz Mac, bet maz ir nepieciešams, lai iet citā virzienā ...)

Mans iespējamo risinājums ir divas daļas - saņemt pastu no Entourage, un pēc tam panākt, lai to uz Outlook.

Getting pastu no Entourage

Par šo daļu, Es uzrakstīju applescript (lielā mērā balstīts uz kodu no macosxhints) eksportēt visas pašreiz izvēlētu e-pastus Entourage uz mapi par manu Mac. Liels paldies macosxhints lietotājam golgi_body par norīkošanu sākotnējo kodu.

Lūk skripts es izmantoju (kopēt to vērā Script Editor, lai to izmantotu):

tell application "Microsoft Entourage"
    -- get a reference to all selected messages from entourage
    set selectedMessages to the current messages
    if selectedMessages is {} then
        return
    end if

    -- absolute reference to our export folder
    set fpath to "DiskName:Users:myusername:Documents:existingfolder:"

    repeat with i in selectedMessages

        set sentDate to time sent of i
        set fname to fpath ¬
            & my padNumber(year of sentDate as integer) ¬
            & "-" & my padNumber(month of sentDate as integer) ¬
            & "-" & my padNumber(day of sentDate as integer) ¬
            & "-" & my padNumber(hours of sentDate as integer) ¬
            & "-" & my padNumber(minutes of sentDate as integer) ¬
            & "-" & my padNumber(seconds of sentDate as integer) ¬

        tell application "Finder"
            if (exists file (fname & ".eml")) then
                set k to 1
                repeat while (exists file (fname & "-" & (k as string) & ".eml"))
                    set k to k + 1
                end repeat
                set fname to (fname & "-" & (k as string))
            end if
        end tell

        set fname to fname & ".eml"
        save i in fname
        tell application "Finder" to update file fname

    end repeat

end tell

to padNumber(theNumber)
    if theNumber is less than 10 then
        return "0" & theNumber
    else
        return theNumber
    end if
end padNumber

Jums būs nepieciešams, lai uzstādītu fpath būt ceļu uz esošu mapi uz jūsu Mac. Palaižot šo skriptu Script Editor, visus izvēlētos failus Entourage tiks eksportēti uz savu eksporta mapē EML failiem.

Kāpēc izmantot AppleScript vispār? Kāpēc ne vienkārši velciet atlasītos e-pastus uz mapi? Galu galā, Tas liek Entourage eksportēt viņiem sevi Eml formātā. Problēma ir, ja jūs to darāt, Entourage eksportē e-pastus, izmantojot e-pasta tēmu kā faila nosaukumu. Tas var ietvert visu veidu dīvaini un brīnišķīgi rakstzīmes, un Windows nepatīk, ka vispār. Šis skripts ļauj izvairīties problēmu vispār ar datumu un laiku, kad e-pasts tika nosūtīts kā filename. (Tas arī ļauj vieglāk pasūtīt savus eml failus pēc datumu un laiku Finder, ja jums ir nepieciešams.)

Getting pastu uz Outlook

Par šo daļu, Es izmantoti Windows lietderība sauc Outlook importēšanas vedni. Tas maksā $19.95, bet tas ir vairāk nekā vērts, ja jūs uzskatāt, kad tas var ietaupīt. To var lejupielādēt un izmēģināt bez maksas (maks 5 e-pastu uz demo importam), bet jābrīdina - demo režīmā, Jūs nevarat ieslēgt "ļautu EML pirmapstrāde (UNIX, MAC)"Iespēja padarīt vednis atzīst Mac kodēti e-pastu, un lai jūsu importētie e-pastu saturēs daudz "=" simboliem, skatot tos Outlook. Labā ziņa ir tā, ka nopirktā lietotne lieliski darbojas ar Mac kodētiem e-pastiem.

Importa process ir diezgan viegli. Datorā ar instalētu programmu Outlook, strādā ar Outlook importēšanas vednis, ir pārliecināts, ka, lai ieslēgtu uz "Iespējot EML pirmapstrāde (UNIX, MAC)"variants (atrodas zem pogas "Options" uz "Select avota mapes" ekrānu) lai pārliecinātos, ka jūsu Mac-kodētas e-pasti tiek atzītas. Vednis ir diezgan pašsaprotams, un ir pilnu instrukcijas tiešsaistē, tāpēc es nedarbosies caur pārējo iestatījumu detalizēti šeit. Lai veiktu importēšanu, būs vajadzīgs laiks, bet galu galā jūs galu galā ar visiem e-pasta ziņojumiem Outlook, ar visiem pielikumiem un oriģinālo galvenes.

Es esmu tikai mēģinājis šo procesu sevi ar Entourage 2008 (uz Leopard) un Outlook 2002 (uz XP), bet es varētu sagaidīt, ka, lai strādātu ar iepriekšējām versijām Entourage pārāk. Outlook importēšanas vednis apgalvo, ka strādā ar Windows 98 / Me / NT 4.0 / 2000 / XP / 2003 ar programmu Outlook 98/2000/2002/2003/2007, tāpēc jums ir jābūt labi iet neatkarīgi no jūsu uzstādīšana.