Mengekspor email dari Entourage ke Outlook

Pasal oleh Dave Addey

Saya baru saja harus mengekspor sekelompok email dari Entourage dan ke Outlook, untuk mengirim mereka ke seseorang dalam format mereka dapat menelusuri dan membaca pada PC. Anda akan berpikir bahwa mengekspor pilihan email dari salah satu alat manajemen email Microsoft yang lain akan mudah, kanan? Sayangnya tidak. Untungnya, sedikit Applescript dan utilitas relatif murah mendapat sesuatu yang bekerja untuk saya. Posting ini menjelaskan bagaimana.

Masalah utama adalah kurangnya format umum antara Entourage (.mbox untuk folder, .eml untuk email individual) dan Outlook (.pst untuk semuanya). Dulu ada alat ekspor Applescript benar-benar baik untuk mengekspor dari Entourage, tapi sayangnya itu tidak pernah diperbarui untuk bekerja pada Leopard. Anda dapat mengekspor seluruh folder sebagai file MBOX dari Entourage, tetapi ini tidak dapat dibuka oleh Outlook dan begitu juga tidak banyak digunakan baik.

(Sebagai samping, ada banyak cara untuk pergi lain cara, ekspor dari Outlook dan diimpor ke Entourage. Ini hampir seolah-olah banyak orang yang beralih dari PC ke Mac, tetapi hanya sedikit perlu pergi ke arah lain ...)

solusi akhirnya saya memiliki dua bagian - mendapatkan email dari Entourage, dan kemudian mendapatkan itu ke Outlook.

Mendapatkan email dari Entourage

Untuk bagian ini, Saya menulis Applescript (berat berdasarkan kode dari MacOSXHints) untuk mengekspor semua email saat-dipilih dalam Entourage ke folder pada Mac saya. Banyak terima kasih kepada MacOSXHints pengguna golgi_body untuk posting kode asli.

Berikut adalah naskah saya menggunakan (copy ini ke Script Editor untuk menggunakannya):

tell application "Microsoft Entourage"
    -- get a reference to all selected messages from entourage
    set selectedMessages to the current messages
    if selectedMessages is {} then
        return
    end if

    -- absolute reference to our export folder
    set fpath to "DiskName:Users:myusername:Documents:existingfolder:"

    repeat with i in selectedMessages

        set sentDate to time sent of i
        set fname to fpath ¬
            & my padNumber(year of sentDate as integer) ¬
            & "-" & my padNumber(month of sentDate as integer) ¬
            & "-" & my padNumber(day of sentDate as integer) ¬
            & "-" & my padNumber(hours of sentDate as integer) ¬
            & "-" & my padNumber(minutes of sentDate as integer) ¬
            & "-" & my padNumber(seconds of sentDate as integer) ¬

        tell application "Finder"
            if (exists file (fname & ".eml")) then
                set k to 1
                repeat while (exists file (fname & "-" & (k as string) & ".eml"))
                    set k to k + 1
                end repeat
                set fname to (fname & "-" & (k as string))
            end if
        end tell

        set fname to fname & ".eml"
        save i in fname
        tell application "Finder" to update file fname

    end repeat

end tell

to padNumber(theNumber)
    if theNumber is less than 10 then
        return "0" & theNumber
    else
        return theNumber
    end if
end padNumber

Anda harus mengatur fpath menjadi path ke folder yang ada di Mac Anda. Ketika Anda menjalankan script ini di Script Editor, semua file yang dipilih dalam Entourage akan diekspor ke folder ekspor Anda sebagai file eml.

Mengapa menggunakan Applescript sama sekali? Mengapa tidak hanya menyeret email yang dipilih ke folder? Lagipula, ini meminta Entourage untuk ekspor mereka sendiri dalam format eml. Masalahnya adalah, ketika Anda melakukannya, Entourage ekspor email menggunakan subjek email sebagai nama file. Ini dapat berisi segala macam karakter aneh dan indah, dan Windows tidak seperti itu sama sekali. Script ini menghindari masalah sama sekali dengan menggunakan tanggal dan waktu email itu dikirim sebagai nama file. (Hal ini juga membuat lebih mudah untuk memesan file eml Anda dengan tanggal dan waktu di Finder jika Anda perlu.)

Mendapatkan email ke Outlook

Untuk bagian ini, Saya menggunakan utilitas Windows yang disebut Outlook Impor Wizard. Ini berharga $19.95, tapi lebih dari layak ketika Anda mempertimbangkan waktu yang dapat menyimpan. Anda dapat men-download dan mencobanya secara gratis (maksimal 5 email per demo impor), tetapi memperingatkan - dalam modus demo, Anda tidak dapat mengaktifkan “Enable yang Preprocessing EML (Unix, MAC)”Pilihan untuk membuat wizard mengenali email Mac-dikodekan, dan email yang diimpor akan berisi banyak “=” simbol saat Anda melihat mereka di Outlook. Kabar baiknya adalah bahwa aplikasi yang dibeli bekerja baik dengan email Mac-dikodekan.

Proses impor cukup mudah. Pada PC Anda dengan Outlook diinstal, bekerja melalui Outlook Wizard Impor, pastikan untuk mengaktifkan “Aktifkan Preprocessing EML (Unix, MAC)"pilihan (ditemukan di bawah tombol “Options” pada “Pilih folder sumber” layar) memastikan bahwa email Anda Mac-dikodekan diakui. wizard cukup jelas, dan ada petunjuk lengkap secara online, jadi saya tidak akan berjalan melalui sisa pengaturan secara rinci di sini. Ini akan memakan waktu cukup lama untuk melakukan impor, tetapi akhirnya Anda akan berakhir dengan semua email Anda di Outlook, dengan semua lampiran dan header asli.

Aku hanya mencoba proses ini sendiri dengan Entourage 2008 (pada Leopard) dan Outlook 2002 (pada XP), tapi saya akan berharap untuk bekerja dengan versi sebelumnya dari Entourage terlalu. Outlook Wizard Impor mengaku bekerja pada Windows 98 / Me / NT 4.0 / 2000 / XP / 2003 dengan Outlook 98/2000/2002/2003/2007, sehingga Anda harus baik untuk pergi tidak peduli apa Anda pengaturan.