ייצוא הודעות דוא ל מ- Entourage Outlook

מאמר מאת דייב Addey

היו לי לאחרונה לייצא חבורה של אימיילים הפמליה לתוך Outlook, על מנת לשלוח אותם למישהו במתכונת הם יכולים לגלוש ולקרוא במחשב. הייתם חושבים כי ייצוא מבחר של אימיילים כלי ניהול דוא"ל אחת לאחרת מיקרוסופט יהיה קל, ימין? למרבה הצער לא. למרבה המזל, קצת AppleScript ואת כלי זול יחסית יש דברים שעובדים בשבילי. פוסט זה מתאר כיצד.

הבעיה העיקרית היא חוסר פורמט נפוץ בין Entourage (.mbox עבור תיקיות, .EML עבור מיילים פרטיים) ו- Outlook (.PST על הכל). בעבר היה כלי יצוא ממש טוב AppleScript ליצוא מן הפמליה, אבל לצערי זה אף פעם לא עודכן לעבוד על נמר. ניתן לייצא תיקייה שלמה כקובץ MBOX מן הפמליה, אבל אלה לא ניתן לפתוח באמצעות Outlook וכך גם לא ממש מועיל או.

(במאמר מוסגר, ישנן דרכים רבות כדי ללכת אחרים דֶרֶך, כדי לייצא מ- Outlook ולייבא לתוך Entourage. זה כמעט כאילו הרבה אנשים עוברים מהמחשב ל- Mac, אבל כמה צריך ללכת בכיוון ההפוך ...)

יש פתרון הסופי שלי לשני חלקים - מקבל מייל מתוך Entourage, ואז מקבל אותו ל- Outlook.

קבלת דואר מתוך Entourage

עבור חלק זה, כתבתי AppleScript (מבוסס במידה רבה על קוד macosxhints) כל הודעות האימייל שנבחרו לייצא ב Entourage לתיקייה ב- Mac שלי. תודות רבות golgi_body המשתמש macosxhints לפרסום את הקוד המקורי.

הנה התסריט אני משתמש (להעתיק זה לתוך עורך תסריט להשתמש בו):

tell application "Microsoft Entourage"
    -- get a reference to all selected messages from entourage
    set selectedMessages to the current messages
    if selectedMessages is {} then
        return
    end if

    -- absolute reference to our export folder
    set fpath to "DiskName:Users:myusername:Documents:existingfolder:"

    repeat with i in selectedMessages

        set sentDate to time sent of i
        set fname to fpath ¬
            & my padNumber(year of sentDate as integer) ¬
            & "-" & my padNumber(month of sentDate as integer) ¬
            & "-" & my padNumber(day of sentDate as integer) ¬
            & "-" & my padNumber(hours of sentDate as integer) ¬
            & "-" & my padNumber(minutes of sentDate as integer) ¬
            & "-" & my padNumber(seconds of sentDate as integer) ¬

        tell application "Finder"
            if (exists file (fname & ".eml")) then
                set k to 1
                repeat while (exists file (fname & "-" & (k as string) & ".eml"))
                    set k to k + 1
                end repeat
                set fname to (fname & "-" & (k as string))
            end if
        end tell

        set fname to fname & ".eml"
        save i in fname
        tell application "Finder" to update file fname

    end repeat

end tell

to padNumber(theNumber)
    if theNumber is less than 10 then
        return "0" & theNumber
    else
        return theNumber
    end if
end padNumber

תצטרך להגדיר fpath להיות נתיב אל תיקייה קיימת ב- Mac שלך. כאשר אתה מפעיל סקריפט זה עורך תסריט, כל הקבצים שנבחרו ב- Entourage ייוצא לתיקיית היצוא שלך כקבצי .eml.

למה להשתמש AppleScript בכלל? למה לא פשוט לגרור את המיילים שנבחרו על תיקייה? אחרי הכל, זה יבקש Entourage לייצא אותם עצמה בפורמט .eml. הבעיה היא, כאשר אתה עושה כך, פמליה מייצאת את הודעות האימייל באמצעות נושא הדוא"ל כשם הקובץ. זה יכול לכלול כל מיני דמויות שונות ומשונות, ו- Windows לא אוהבת את זה בכלל. סקריפט זה ימנע את הבעיה לחלוטין באמצעות התאריך והשעה שבהם נשלח האימייל כמו שם הקובץ. (זה גם מקל להורות קבצים .eml שלך לפי תאריך ושעה ב- Finder אם אתה צריך.)

קבלת דואר ל- Outlook

עבור חלק זה, השתמשתי בכלי שנקרא Windows אשף הייבוא של outlook. זה עולה $19.95, אבל זה יותר שווה את זה כאשר אתה מחשיב את הזמן זה יכול לחסוך. אתה יכול להוריד אותו לנסות את זה בחינם (מקסימום 5 מיילים לכל יבוא הדגמה), אבל ראו הוזהרתם - במצב הדגמה, אתה לא יכול להדליק את "Enable החל בעיבוד EML (יוניקס, מק)" אפשרות להפוך לאשף לזהות הודעות דוא"ל Mac בקידוד, וכך המיילים המיובאים שלך יכילו הרבה "=" סימנים בעת ההצגה אותם ב- Outlook. החדשות הטובות הן כי היישום שנרכש עובד מצוין עם מיילים בקידוד Mac.

תהליך היבוא הוא די קל. במחשב עם Outlook מותקן, לעבוד דרך אשף ייבוא ​​Outlook, להיות בטוח כדי להפעיל את "Enable החלו בעיבוד EML (יוניקס, מק)"אפשרות (נמצא תחת הכפתור "אפשרויות" על המסך "בחר את תיקיית המקור") כדי לוודא כי מייל Mac שלך מקודד מוכרים. האשף הוא מובן מאליו די, ויש מלאות אחר הוראות מקוונות, אז אני לא אפעל דרך שאר ההגדרות בפירוט כאן. זה ייקח קצת זמן לעשות את היבוא, אבל בסופו של דבר תקבל בסופו של דבר עם כל האימיילים שלכם ב- Outlook, עם כל הקבצים המצורפים ואת הכותרות המקוריות.

ניסיתי רק זה תהליך עצמי עם פמליה 2008 (על נמר) ו- Outlook 2002 (על XP), אבל הייתי מצפה שזה יעבוד עם גרסאות מוקדמות יותר של Entourage מדי. אשף ייבוא ​​Outlook טוען לעבוד על Windows 98 / Me / NT 4.0 / 2000 / XP / 2003 עם Outlook 98/2000/2002/2003/2007, אז אתה צריך להיות טוב ללכת לא משנה מה ההגדרה שלך.