Eksport e-mails fra Entourage til Outlook

Artikel af Dave Addey

Jeg har for nylig haft til at eksportere en masse e-mails fra Entourage og i Outlook, med henblik på at sende dem til en person i et format, de kan gennemse og læse på en pc. Man skulle tro, at eksport af et udvalg af e-mails fra en Microsoft e-mail ledelsesværktøj til en anden ville være let, højre? Desværre ikke. Heldigvis, lidt af Applescript og en relativt billig hjælpeprogram fik ting at arbejde for mig. Dette indlæg beskriver, hvordan.

Det største problem er manglen på et fælles format mellem Entourage (.mbox til mapper, .eml for individuelle e-mails) og Outlook (.pst for alt). Der plejede at være en rigtig god Applescript eksport værktøj til at eksportere fra Entourage, men desværre er det aldrig blevet opdateret til at arbejde på Leopard. Du kan eksportere en hel mappe som en MBOX fil fra Entourage, men disse kan ikke åbnes af Outlook og så er der ikke meget brug enten.

(Som en sidebemærkning, der er mange måder at gå den andre vej, at eksportere fra Outlook og importere i Entourage. Det er næsten som om masser af mennesker skifter fra PC til Mac, men få brug for at gå i den anden retning ...)

Min endelige løsning har to dele - at få post ud af Entourage, og så få det på Outlook.

Kom mail ud af Entourage

Til denne del, Jeg skrev en Applescript (baseret tungt på en kode fra macosxhints) at eksportere alle aktuelt udvalgte e-mails i Entourage til en mappe på min Mac. Mange tak til macosxhints bruger golgi_body for udstationering den oprindelige kode.

Her er scriptet jeg bruger (kopiere denne ind i Script Editor til at bruge det):

tell application "Microsoft Entourage"
    -- get a reference to all selected messages from entourage
    set selectedMessages to the current messages
    if selectedMessages is {} then
        return
    end if

    -- absolute reference to our export folder
    set fpath to "DiskName:Users:myusername:Documents:existingfolder:"

    repeat with i in selectedMessages

        set sentDate to time sent of i
        set fname to fpath ¬
            & my padNumber(year of sentDate as integer) ¬
            & "-" & my padNumber(month of sentDate as integer) ¬
            & "-" & my padNumber(day of sentDate as integer) ¬
            & "-" & my padNumber(hours of sentDate as integer) ¬
            & "-" & my padNumber(minutes of sentDate as integer) ¬
            & "-" & my padNumber(seconds of sentDate as integer) ¬

        tell application "Finder"
            if (exists file (fname & ".eml")) then
                set k to 1
                repeat while (exists file (fname & "-" & (k as string) & ".eml"))
                    set k to k + 1
                end repeat
                set fname to (fname & "-" & (k as string))
            end if
        end tell

        set fname to fname & ".eml"
        save i in fname
        tell application "Finder" to update file fname

    end repeat

end tell

to padNumber(theNumber)
    if theNumber is less than 10 then
        return "0" & theNumber
    else
        return theNumber
    end if
end padNumber

Du skal angive fpath at være vejen til en eksisterende mappe på din Mac. Når du kører dette script i Script Editor, alle de valgte filer i Entourage vil blive eksporteret til din eksport mappe som eml filer.

Hvorfor bruge Applescript overhovedet? Hvorfor ikke bare trække de valgte e-mails til en mappe? Trods alt, denne udvikling får Entourage at eksportere dem selv i .eml format. Problemet er, når du gør det, Entourage eksporterer de e-mails med email emnet som filnavnet. Dette kan indeholde alle mulige underlige og vidunderlige tegn, og Windows kan ikke lide, at der på alle. Dette script undgår problemet helt ved hjælp af dato og klokkeslæt e-mailen blev sendt som filnavnet. (Det gør det også nemmere at bestille din eml filer efter dato og tid i Finder, hvis du skal.)

At få mail på Outlook

Til denne del, Jeg brugte en Windows-hjælpeprogram kaldet Outlook Import Wizard. Det koster $19.95, men det er mere end det værd, når man tænker på den tid, det kan spare. Du kan downloade det og prøve det gratis (max 5 e-mails pr demo import), men blive advaret - i demo-tilstand, du kan ikke tænde for ”aktivere EML Forbehandling (UNIX, MAC)”Mulighed for at gøre guiden genkende Mac-kodede e-mails, og så dine importerede e-mails vil indeholde masser af ”=” symboler, når du ser dem i Outlook. Den gode nyhed er, at det købte app fungerer fint med Mac-kodede e-mails.

Importen er temmelig let. På din pc med Outlook installeret, arbejde gennem guiden Outlook, være sikker på at tænde for ”Aktiver EML Forbehandling (UNIX, MAC)"valgmulighed (findes under knappen ”Indstillinger” på ”Vælg den kilde mappe” skærm) at sikre, at dine Mac-kodede e-mails er anerkendt. Guiden er temmelig selvforklarende, og der er fulde vejledning online, så jeg vil ikke løbe gennem resten af ​​indstillingerne i detaljer her. Det vil tage et stykke tid at gøre import, men i sidste ende vil du ende op med alle dine e-mails i Outlook, med alle vedhæftede filer og de oprindelige overskrifter.

Jeg har kun prøvet denne proces selv med Entourage 2008 (på Leopard) og Outlook 2002 (på XP), men jeg ville forvente det at arbejde med tidligere versioner af Entourage også. Import Wizard Outlook hævder at arbejde på Windows 98 / Me / NT 4.0 / 2000 / XP / 2003 med Outlook 98/2000/2002/2003/2007, så du skal være god til at gå, uanset hvad din opsætning.